src/util/niclist.pl

   1 #!/usr/bin/env perl
   2 #
   3 # Generates list of supported NICs with PCI vendor/device IDs, driver name
   4 # and other useful things.
   5 #
   6 # Initial version by Robin Smidsrød <robin@smidsrod.no>
   7 #
   8
   9 use strict;
  10 use warnings;
  11 use autodie;
  12 use v5.10;
  13
  14 use File::stat;
  15 use File::Basename qw(basename);
  16 use File::Find ();
  17 use Getopt::Long qw(GetOptions);
  18
  19 GetOptions(
  20     'help'       => \( my $help     = 0      ),
  21     'format=s'   => \( my $format   = 'text' ),
  22     'sort=s'     => \( my $sort     = 'bus,ipxe_driver,ipxe_name' ),
  23     'columns=s'  => \( my $columns  = 'bus,vendor_id,device_id,'
  24                                     . 'vendor_name,device_name,ipxe_driver,'
  25                                     . 'ipxe_name,ipxe_description,file,legacy_api'
  26                      ),
  27     'pci-url=s'  => \( my $pci_url  = 'http://pciids.sourceforge.net/v2.2/pci.ids' ),
  28     'pci-file=s' => \( my $pci_file = '/tmp/pci.ids' ),
  29     'output=s'   => \( my $output   = '' ),
  30 );
  31
  32 die(<<"EOM") if $help;
  33 Usage: $0 [options] [<directory>]
  34
  35 Options:
  36     --help     This page
  37     --format   Set output format
  38     --sort     Set output sort order (comma-separated)
  39     --columns  Set output columns (comma-separated)
  40     --pci-url  URL to pci.ids file
  41     --pci-file Cache file for downloaded pci.ids
  42     --output   Output file (not specified is STDOUT)
  43
  44 Output formats:
  45     text, csv, json, html, dokuwiki
  46
  47 Column names (default order):
  48     bus, vendor_id, device_id, vendor_name, device_name,
  49     ipxe_driver, ipxe_name, ipxe_description, file, legacy_api
  50 EOM
  51
  52 # Only load runtime requirements if actually in use
  53 given($format) {
  54     when( /csv/  ) {
  55                        eval { require Text::CSV; };
  56                        die("Please install Text::CSV CPAN module to use this feature.\n")
  57                            if $@;
  58                    }
  59     when( /json/ ) {
  60                        eval { require JSON; };
  61                        die("Please install JSON CPAN module to use this feature.\n")
  62                            if $@;
  63                    }
  64     when( /html/ ) {
  65                        eval { require HTML::Entities; };
  66                        die("Please install HTML::Entities CPAN module to use this feature.\n")
  67                            if $@;
  68                    }
  69     default        { }
  70 }
  71
  72 # Scan source dir and build NIC list
  73 my $ipxe_src_dir = shift || '.'; # Default to current directory
  74 my $ipxe_nic_list = build_ipxe_nic_list( $ipxe_src_dir );
  75
  76 # Download pci.ids file and parse it
  77 fetch_pci_ids_file($pci_url, $pci_file);
  78 my $pci_id_map = build_pci_id_map($pci_file);
  79
  80 # Merge 'official' vendor/device names and sort list
  81 update_ipxe_nic_names($ipxe_nic_list, $pci_id_map);
  82 my $sorted_list = sort_ipxe_nic_list($ipxe_nic_list, $sort);
  83
  84 # Run specified formatter
  85 my $column_names = parse_columns_param($columns);
  86 say STDERR "Formatting NIC list in format '$format' with columns: "
  87          . join(", ", @$column_names);
  88 my $formatter = \&{ "format_nic_list_$format" };
  89 my $report = $formatter->( $sorted_list, $column_names );
  90
  91 # Print final report
  92 if ( $output and $output ne '-' ) {
  93     say STDERR "Printing report to '$output'...";
  94     open( my $out_fh, ">", $output );
  95     print $out_fh $report;
  96     close($out_fh);
  97 }
  98 else {
  99     print STDOUT $report;
 100 }
 101
 102 exit;
 103
 104 # fetch URL into specified filename
 105 sub fetch_pci_ids_file {
 106     my ($url, $filename) = @_;
 107     my @cmd = ( "wget", "--quiet", "-O", $filename, $url );
 108     my @touch = ( "touch", $filename );
 109     if ( -r $filename ) {
 110         my $age = time - stat($filename)->mtime;
 111         # Refresh if older than 1 day
 112         if ( $age > 86400 ) {
 113             say STDERR "Refreshing $filename from $url...";
 114             system(@cmd);
 115             system(@touch);
 116         }
 117     }
 118     else {
 119         say STDERR "Fetching $url into $filename...";
 120         system(@cmd);
 121         system(@touch);
 122     }
 123     return $filename;
 124 }
 125
 126 sub build_pci_id_map {
 127     my ($filename) = @_;
 128     say STDERR "Building PCI ID map...";
 129
 130     my $devices = {};
 131     my $classes = {};
 132     my $pci_id = qr/[[:xdigit:]]{4}/;
 133     my $c_id = qr/[[:xdigit:]]{2}/;
 134     my $non_space = qr/[^\s]/;
 135
 136     # open pci.ids file specified
 137     open( my $fh, "<", $filename );
 138
 139     # For devices
 140     my $vendor_id = "";
 141     my $vendor_name = "";
 142     my $device_id = "";
 143     my $device_name = "";
 144
 145     # For classes
 146     my $class_id = "";
 147     my $class_name = "";
 148     my $subclass_id = "";
 149     my $subclass_name = "";
 150
 151     while(<$fh>) {
 152         # skip # and blank lines
 153         next if m/^$/;
 154         next if m/^\s*#/;
 155
 156         # Vendors, devices and subsystems. Please keep sorted.
 157         # Syntax:
 158         # vendor  vendor_name
 159         #   device  device_name             <-- single tab
 160         #       subvendor subdevice  subsystem_name <-- two tabs
 161         if ( m/^ ($pci_id) \s+ ( $non_space .* ) /x ) {
 162             $vendor_id = lc $1;
 163             $vendor_name = $2;
 164             $devices->{$vendor_id} = { name => $vendor_name };
 165             next;
 166         }
 167
 168         if ( $vendor_id and m/^ \t ($pci_id) \s+ ( $non_space .* ) /x ) {
 169             $device_id = lc $1;
 170             $device_name = $2;
 171             $devices->{$vendor_id}->{'devices'} //= {};
 172             $devices->{$vendor_id}->{'devices'}->{$device_id} = { name => $device_name };
 173             next;
 174         }
 175
 176         if ( $vendor_id and $device_id and m/^ \t{2} ($pci_id) \s+ ($pci_id) \s+ ( $non_space .* ) /x ) {
 177             my $subvendor_id = lc $1;
 178             my $subdevice_id = lc $2;
 179             my $subsystem_name = $3;
 180             $devices->{$vendor_id}->{'devices'}->{$device_id}->{'subvendor'} //= {};
 181             $devices->{$vendor_id}->{'devices'}->{$device_id}->{'subvendor'}->{$subvendor_id} //= {};
 182             $devices->{$vendor_id}->{'devices'}->{$device_id}->{'subvendor'}->{$subvendor_id}->{'devices'} //= {};
 183             $devices->{$vendor_id}->{'devices'}->{$device_id}->{'subvendor'}->{$subvendor_id}->{'devices'}->{$subdevice_id} = { name => $subsystem_name };
 184             next;
 185         }
 186
 187         # List of known device classes, subclasses and programming interfaces
 188         # Syntax:
 189         # C class   class_name
 190         #   subclass    subclass_name       <-- single tab
 191         #       prog-if  prog-if_name   <-- two tabs
 192         if ( m/^C \s+ ($c_id) \s+ ( $non_space .* ) /x ) {
 193             $class_id = lc $1;
 194             $class_name = $2;
 195             $classes->{$class_id} = { name => $class_name };
 196             next;
 197         }
 198
 199         if ( $class_id and m/^ \t ($c_id) \s+ ( $non_space .* ) /x ) {
 200             $subclass_id = lc $1;
 201             $subclass_name = $2;
 202             $classes->{$class_id}->{'subclasses'} //= {};
 203             $classes->{$class_id}->{'subclasses'}->{$subclass_id} = { name => $subclass_name };
 204             next;
 205         }
 206
 207         if ( $class_id and $subclass_id and m/^ \t{2} ($c_id) \s+ ( $non_space .* )  /x ) {
 208             my $prog_if_id = lc $1;
 209             my $prog_if_name = $2;
 210             $classes->{$class_id}->{'subclasses'}->{$subclass_id}->{'programming_interfaces'} //= {};
 211             $classes->{$class_id}->{'subclasses'}->{$subclass_id}->{'programming_interfaces'}->{$prog_if_id} = { name => $prog_if_name };
 212             next;
 213         }
 214     }
 215
 216     close($fh);
 217
 218     # Populate subvendor names
 219     foreach my $vendor_id ( keys %$devices ) {
 220         my $device_map = $devices->{$vendor_id}->{'devices'};
 221         foreach my $device_id ( keys %$device_map ) {
 222             my $subvendor_map = $device_map->{$device_id}->{'subvendor'};
 223             foreach my $subvendor_id ( keys %$subvendor_map ) {
 224                 $subvendor_map->{$subvendor_id}->{'name'} = $devices->{$subvendor_id}->{'name'} || "";
 225             }
 226         }
 227     }
 228
 229     return {
 230         'devices' => $devices,
 231         'classes' => $classes,
 232     };
 233 }
 234
 235 # Scan through C code and parse ISA_ROM and PCI_ROM lines
 236 sub build_ipxe_nic_list {
 237     my ($dir) = @_;
 238     say STDERR "Building iPXE NIC list from " . ( $dir eq '.' ? 'current directory' : $dir ) . "...";
 239
 240     # recursively iterate through dir and find .c files
 241     my @c_files;
 242     File::Find::find(sub {
 243         # only process files
 244         return if -d $_;
 245         # skip unreadable files
 246         return unless -r $_;
 247         # skip all but files with .c extension
 248         return unless /\.c$/;
 249         push @c_files, $File::Find::name;
 250     }, $dir);
 251
 252     # Look for ISA_ROM or PCI_ROM lines
 253     my $ipxe_nic_list = [];
 254     my $hex_id = qr/0 x [[:xdigit:]]{4} /x;
 255     my $quote = qr/ ['"] /x;
 256     my $non_space = qr/ [^\s] /x;
 257     my $rom_line_counter = 0;
 258     foreach my $c_path ( sort @c_files ) {
 259         my $legacy = 0;
 260         open( my $fh, "<", $c_path );
 261         my $c_file = $c_path;
 262         $c_file =~ s{^\Q$dir\E/?}{} if -d $dir; # Strip directory from reported filename
 263         my $ipxe_driver = basename($c_file, '.c');
 264         while(<$fh>) {
 265             # Most likely EtherBoot legacy API
 266             $legacy = 1 if m/struct \s* nic \s*/x;
 267
 268             # parse ISA|PCI_ROM lines into hashref and append to $ipxe_nic_list
 269             next unless m/^ \s* (?:ISA|PCI)_ROM /x;
 270             $rom_line_counter++;
 271             chomp;
 272             #say; # for debugging regexp
 273             if ( m/^ \s* ISA_ROM \s* \( \s* $quote ( .*? ) $quote \s* , \s* $quote ( .*? ) $quote \s* \) /x ) {
 274                 my $image = $1;
 275                 my $name = $2;
 276                 push @$ipxe_nic_list, {
 277                     file             => $c_file,
 278                     bus              => 'isa',
 279                     ipxe_driver      => $ipxe_driver,
 280                     ipxe_name        => $image,
 281                     ipxe_description => $name,
 282                     legacy_api       => ( $legacy ? 'yes' : 'no' ),
 283                 };
 284                 next;
 285             }
 286             if ( m/^ \s* PCI_ROM \s* \( \s* ($hex_id) \s* , \s* ($hex_id) \s* , \s* $quote (.*?) $quote \s* , \s* $quote (.*?) $quote /x ) {
 287                 my $vendor_id = lc $1;
 288                 my $device_id = lc $2;
 289                 my $name = $3;
 290                 my $desc = $4;
 291                 push @$ipxe_nic_list, {
 292                     file             => $c_file,
 293                     bus              => 'pci',
 294                     vendor_id        => substr($vendor_id, 2), # strip 0x
 295                     device_id        => substr($device_id, 2), # strip 0x
 296                     ipxe_driver      => $ipxe_driver,
 297                     ipxe_name        => $name,
 298                     ipxe_description => $desc,
 299                     legacy_api       => ( $legacy ? 'yes' : 'no' ),
 300                 };
 301                 next;
 302             }
 303         }
 304         close($fh);
 305     }
 306
 307     # Verify all ROM lines where parsed properly
 308     my @isa_roms = grep { $_->{'bus'} eq 'isa' } @$ipxe_nic_list;
 309     my @pci_roms = grep { $_->{'bus'} eq 'pci' } @$ipxe_nic_list;
 310     if ( $rom_line_counter != ( @isa_roms + @pci_roms ) ) {
 311         say STDERR "Found ROM lines: $rom_line_counter";
 312         say STDERR "Extracted ISA_ROM lines: " . scalar @isa_roms;
 313         say STDERR "Extracted PCI_ROM lines: " . scalar @pci_roms;
 314         die("Mismatch between number of ISA_ROM/PCI_ROM lines and extracted entries. Verify regular expressions.\n");
 315     }
 316
 317     return $ipxe_nic_list;
 318 }
 319
 320 # merge vendor/product name from $pci_id_map into $ipxe_nic_list
 321 sub update_ipxe_nic_names {
 322     my ($ipxe_nic_list, $pci_id_map) = @_;
 323     say STDERR "Merging 'official' vendor/device names...";
 324
 325     foreach my $nic ( @$ipxe_nic_list ) {
 326         next unless $nic->{'bus'} eq 'pci';
 327         $nic->{'vendor_name'} = $pci_id_map->{'devices'}->{ $nic->{'vendor_id'} }->{'name'} || "";
 328         $nic->{'device_name'} = $pci_id_map->{'devices'}->{ $nic->{'vendor_id'} }->{'devices'}->{ $nic->{'device_id'} }->{'name'} || "";
 329     }
 330     return $ipxe_nic_list; # Redundant, as we're mutating the input list, useful for chaining calls
 331 }
 332
 333 # Sort entries in NIC list according to sort criteria
 334 sub sort_ipxe_nic_list {
 335     my ($ipxe_nic_list, $sort_column_names) = @_;
 336     my @sort_column_names = @{ parse_columns_param($sort_column_names) };
 337     say STDERR "Sorting NIC list by: " . join(", ", @sort_column_names );
 338     # Start at the end of the list and resort until list is exhausted
 339     my @sorted_list = @{ $ipxe_nic_list };
 340     while(@sort_column_names) {
 341         my $column_name = pop @sort_column_names;
 342         @sorted_list = sort { ( $a->{$column_name} || "" ) cmp ( $b->{$column_name} || "" ) }
 343                        @sorted_list;
 344     }
 345     return \@sorted_list;
 346 }
 347
 348 # Parse comma-separated values into array
 349 sub parse_columns_param {
 350     my ($columns) = @_;
 351     return [
 352         grep { is_valid_column($_) } # only include valid entries
 353         map  { s/\s//g; $_; }        # filter whitespace
 354         split( /,/, $columns )       # split on comma
 355     ];
 356 }
 357
 358 # Return true if the input column name is valid
 359 sub is_valid_column {
 360     my ($name) = @_;
 361     my $valid_column_map = {
 362         map { $_ => 1 }
 363         qw(
 364            bus file legacy_api
 365            ipxe_driver ipxe_name ipxe_description
 366            vendor_id device_id vendor_name device_name
 367         )
 368     };
 369     return unless $name;
 370     return unless $valid_column_map->{$name};
 371     return 1;
 372 }
 373
 374 # Output NIC list in plain text
 375 sub format_nic_list_text {
 376     my ($nic_list, $column_names) = @_;
 377     return join("\n",
 378         map { format_nic_text($_, $column_names) }
 379         @$nic_list
 380     );
 381 }
 382
 383 # Format one ipxe_nic_list entry for display
 384 # Column order not supported by text format
 385 sub format_nic_text {
 386     my ($nic, $column_names) = @_;
 387     my $labels = {
 388         bus              => 'Bus:             ',
 389         ipxe_driver      => 'iPXE driver:     ',
 390         ipxe_name        => 'iPXE name:       ',
 391         ipxe_description => 'iPXE description:',
 392         file             => 'Source file:     ',
 393         legacy_api       => 'Using legacy API:',
 394         vendor_id        => 'PCI vendor ID:   ',
 395         device_id        => 'PCI device ID:   ',
 396         vendor_name      => 'Vendor name:     ',
 397         device_name      => 'Device name:     ',
 398     };
 399     my $pci_only = {
 400         vendor_id   => 1,
 401         device_id   => 1,
 402         vendor_name => 1,
 403         device_name => 1,
 404     };
 405     my $output = "";
 406     foreach my $column ( @$column_names ) {
 407         next if $nic->{'bus'} eq 'isa' and $pci_only->{$column};
 408         $output .= $labels->{$column}
 409                 .  " "
 410                 . ( $nic->{$column} || "" )
 411                 . "\n";
 412     }
 413     return $output;
 414 }
 415
 416 # Output NIC list in JSON
 417 sub format_nic_list_json {
 418     my ($nic_list, $column_names) = @_;
 419
 420     # Filter columns not mentioned
 421     my @nics;
 422     foreach my $nic ( @$nic_list ) {
 423         my $filtered_nic = {};
 424         foreach my $key ( @$column_names ) {
 425             $filtered_nic->{$key} = $nic->{$key};
 426         }
 427         push @nics, $filtered_nic;
 428     }
 429
 430     return JSON->new->pretty->utf8->encode(\@nics);
 431 }
 432
 433 # Output NIC list in CSV
 434 sub format_nic_list_csv {
 435     my ($nic_list, $column_names) = @_;
 436     my @output;
 437
 438     # Output CSV header
 439     my $csv = Text::CSV->new();
 440     if ( $csv->combine( @$column_names ) ) {
 441         push @output, $csv->string();
 442     }
 443
 444     # Output CSV lines
 445     foreach my $nic ( @$nic_list ) {
 446         my @columns = @{ $nic }{ @$column_names };
 447         if ( $csv->combine( @columns ) ) {
 448             push @output, $csv->string();
 449         }
 450     }
 451     return join("\n", @output) . "\n";
 452 }
 453
 454 # Output NIC list in HTML
 455 sub format_nic_list_html {
 456     my ($nic_list, $column_names) = @_;
 457     my @output;
 458
 459     push @output, <<'EOM';
 460 <!DOCTYPE html>
 461 <html>
 462 <head>
 463 <meta charset="utf-8">
 464 <title>Network cards supported by iPXE</title>
 465 <style>
 466 table.tablesorter {
 467  border: thin solid black;
 468 }
 469
 470 table.tablesorter thead {
 471  background-color: #EEE;
 472 }
 473
 474 table.tablesorter thead th {
 475  font-weight: bold;
 476 }
 477
 478 table.tablesorter tbody td {
 479  vertical-align: top;
 480  padding-left: 0.25em;
 481  padding-right: 0.25em;
 482  padding-bottom: 0.125em;
 483  white-space: nowrap;
 484 }
 485
 486 table.tablesorter tbody tr.even {
 487  background-color: #eee;
 488 }
 489
 490 table.tablesorter tbody tr.odd {
 491  background-color: #fff;
 492 }
 493 </style>
 494 </head>
 495 <body>
 496 <h1>Network cards supported by iPXE</h1>
 497 <table class="tablesorter">
 498 <thead>
 499 EOM
 500
 501     # Output HTML header
 502     push @output, "<tr>"
 503                 . join("",
 504                     map { "<th>" . HTML::Entities::encode($_) . "</th>" }
 505                     @$column_names
 506                   )
 507                 . "</tr>";
 508
 509     push @output, <<"EOM";
 510 </thead>
 511 <tbody>
 512 EOM
 513     # Output HTML lines
 514     my $counter = 0;
 515     foreach my $nic ( @$nic_list ) {
 516         my @columns = @{ $nic }{ @$column_names }; # array slice from hashref, see perldoc perldata if confusing
 517         push @output, q!<tr class="! . ( $counter % 2 ? 'even' : 'odd' ) . q!">!
 518                     . join("",
 519                         map { "<td>" . HTML::Entities::encode( $_ || "" ) . "</td>" }
 520                         @columns
 521                       )
 522                     . "</tr>";
 523         $counter++;
 524     }
 525
 526     push @output, <<'EOM';
 527 </tbody>
 528 </table>
 529 <script type="text/javascript" src="http://ajax.googleapis.com/ajax/libs/jquery/1.7.1/jquery.min.js"></script>
 530 <script>
 531 /*
 532  *
 533  * TableSorter 2.0 - Client-side table sorting with ease!
 534  * Version 2.0.5b
 535  * @requires jQuery v1.2.3
 536  * From http://tablesorter.com/
 537  *
 538  * Copyright (c) 2007 Christian Bach
 539  * Examples and docs at: http://tablesorter.com
 540  * Dual licensed under the MIT and GPL licenses:
 541  * http://www.opensource.org/licenses/mit-license.php
 542  * http://www.gnu.org/licenses/gpl.html
 543  *
 544  */
 545 (function($){$.extend({tablesorter:new
 546 function(){var parsers=[],widgets=[];this.defaults={cssHeader:"header",cssAsc:"headerSortUp",cssDesc:"headerSortDown",cssChildRow:"expand-child",sortInitialOrder:"asc",sortMultiSortKey:"shiftKey",sortForce:null,sortAppend:null,sortLocaleCompare:true,textExtraction:"simple",parsers:{},widgets:[],widgetZebra:{css:["even","odd"]},headers:{},widthFixed:false,cancelSelection:true,sortList:[],headerList:[],dateFormat:"us",decimal:'/\.|\,/g',onRenderHeader:null,selectorHeaders:'thead th',debug:false};function benchmark(s,d){log(s+","+(new Date().getTime()-d.getTime())+"ms");}this.benchmark=benchmark;function log(s){if(typeof console!="undefined"&&typeof console.debug!="undefined"){console.log(s);}else{alert(s);}}function buildParserCache(table,$headers){if(table.config.debug){var parsersDebug="";}if(table.tBodies.length==0)return;var rows=table.tBodies[0].rows;if(rows[0]){var list=[],cells=rows[0].cells,l=cells.length;for(var i=0;i<l;i++){var p=false;if($.metadata&&($($headers[i]).metadata()&&$($headers[i]).metadata().sorter)){p=getParserById($($headers[i]).metadata().sorter);}else if((table.config.headers[i]&&table.config.headers[i].sorter)){p=getParserById(table.config.headers[i].sorter);}if(!p){p=detectParserForColumn(table,rows,-1,i);}if(table.config.debug){parsersDebug+="column:"+i+" parser:"+p.id+"\n";}list.push(p);}}if(table.config.debug){log(parsersDebug);}return list;};function detectParserForColumn(table,rows,rowIndex,cellIndex){var l=parsers.length,node=false,nodeValue=false,keepLooking=true;while(nodeValue==''&&keepLooking){rowIndex++;if(rows[rowIndex]){node=getNodeFromRowAndCellIndex(rows,rowIndex,cellIndex);nodeValue=trimAndGetNodeText(table.config,node);if(table.config.debug){log('Checking if value was empty on row:'+rowIndex);}}else{keepLooking=false;}}for(var i=1;i<l;i++){if(parsers[i].is(nodeValue,table,node)){return parsers[i];}}return parsers[0];}function getNodeFromRowAndCellIndex(rows,rowIndex,cellIndex){return rows[rowIndex].cells[cellIndex];}function trimAndGetNodeText(config,node){return $.trim(getElementText(config,node));}function getParserById(name){var l=parsers.length;for(var i=0;i<l;i++){if(parsers[i].id.toLowerCase()==name.toLowerCase()){return parsers[i];}}return false;}function buildCache(table){if(table.config.debug){var cacheTime=new Date();}var totalRows=(table.tBodies[0]&&table.tBodies[0].rows.length)||0,totalCells=(table.tBodies[0].rows[0]&&table.tBodies[0].rows[0].cells.length)||0,parsers=table.config.parsers,cache={row:[],normalized:[]};for(var i=0;i<totalRows;++i){var c=$(table.tBodies[0].rows[i]),cols=[];if(c.hasClass(table.config.cssChildRow)){cache.row[cache.row.length-1]=cache.row[cache.row.length-1].add(c);continue;}cache.row.push(c);for(var j=0;j<totalCells;++j){cols.push(parsers[j].format(getElementText(table.config,c[0].cells[j]),table,c[0].cells[j]));}cols.push(cache.normalized.length);cache.normalized.push(cols);cols=null;};if(table.config.debug){benchmark("Building cache for "+totalRows+" rows:",cacheTime);}return cache;};function getElementText(config,node){var text="";if(!node)return"";if(!config.supportsTextContent)config.supportsTextContent=node.textContent||false;if(config.textExtraction=="simple"){if(config.supportsTextContent){text=node.textContent;}else{if(node.childNodes[0]&&node.childNodes[0].hasChildNodes()){text=node.childNodes[0].innerHTML;}else{text=node.innerHTML;}}}else{if(typeof(config.textExtraction)=="function"){text=config.textExtraction(node);}else{text=$(node).text();}}return text;}function appendToTable(table,cache){if(table.config.debug){var appendTime=new Date()}var c=cache,r=c.row,n=c.normalized,totalRows=n.length,checkCell=(n[0].length-1),tableBody=$(table.tBodies[0]),rows=[];for(var i=0;i<totalRows;i++){var pos=n[i][checkCell];rows.push(r[pos]);if(!table.config.appender){var l=r[pos].length;for(var j=0;j<l;j++){tableBody[0].appendChild(r[pos][j]);}}}if(table.config.appender){table.config.appender(table,rows);}rows=null;if(table.config.debug){benchmark("Rebuilt table:",appendTime);}applyWidget(table);setTimeout(function(){$(table).trigger("sortEnd");},0);};function buildHeaders(table){if(table.config.debug){var time=new Date();}var meta=($.metadata)?true:false;var header_index=computeTableHeaderCellIndexes(table);$tableHeaders=$(table.config.selectorHeaders,table).each(function(index){this.column=header_index[this.parentNode.rowIndex+"-"+this.cellIndex];this.order=formatSortingOrder(table.config.sortInitialOrder);this.count=this.order;if(checkHeaderMetadata(this)||checkHeaderOptions(table,index))this.sortDisabled=true;if(checkHeaderOptionsSortingLocked(table,index))this.order=this.lockedOrder=checkHeaderOptionsSortingLocked(table,index);if(!this.sortDisabled){var $th=$(this).addClass(table.config.cssHeader);if(table.config.onRenderHeader)table.config.onRenderHeader.apply($th);}table.config.headerList[index]=this;});if(table.config.debug){benchmark("Built headers:",time);log($tableHeaders);}return $tableHeaders;};function computeTableHeaderCellIndexes(t){var matrix=[];var lookup={};var thead=t.getElementsByTagName('THEAD')[0];var trs=thead.getElementsByTagName('TR');for(var i=0;i<trs.length;i++){var cells=trs[i].cells;for(var j=0;j<cells.length;j++){var c=cells[j];var rowIndex=c.parentNode.rowIndex;var cellId=rowIndex+"-"+c.cellIndex;var rowSpan=c.rowSpan||1;var colSpan=c.colSpan||1
 547 var firstAvailCol;if(typeof(matrix[rowIndex])=="undefined"){matrix[rowIndex]=[];}for(var k=0;k<matrix[rowIndex].length+1;k++){if(typeof(matrix[rowIndex][k])=="undefined"){firstAvailCol=k;break;}}lookup[cellId]=firstAvailCol;for(var k=rowIndex;k<rowIndex+rowSpan;k++){if(typeof(matrix[k])=="undefined"){matrix[k]=[];}var matrixrow=matrix[k];for(var l=firstAvailCol;l<firstAvailCol+colSpan;l++){matrixrow[l]="x";}}}}return lookup;}function checkCellColSpan(table,rows,row){var arr=[],r=table.tHead.rows,c=r[row].cells;for(var i=0;i<c.length;i++){var cell=c[i];if(cell.colSpan>1){arr=arr.concat(checkCellColSpan(table,headerArr,row++));}else{if(table.tHead.length==1||(cell.rowSpan>1||!r[row+1])){arr.push(cell);}}}return arr;};function checkHeaderMetadata(cell){if(($.metadata)&&($(cell).metadata().sorter===false)){return true;};return false;}function checkHeaderOptions(table,i){if((table.config.headers[i])&&(table.config.headers[i].sorter===false)){return true;};return false;}function checkHeaderOptionsSortingLocked(table,i){if((table.config.headers[i])&&(table.config.headers[i].lockedOrder))return table.config.headers[i].lockedOrder;return false;}function applyWidget(table){var c=table.config.widgets;var l=c.length;for(var i=0;i<l;i++){getWidgetById(c[i]).format(table);}}function getWidgetById(name){var l=widgets.length;for(var i=0;i<l;i++){if(widgets[i].id.toLowerCase()==name.toLowerCase()){return widgets[i];}}};function formatSortingOrder(v){if(typeof(v)!="Number"){return(v.toLowerCase()=="desc")?1:0;}else{return(v==1)?1:0;}}function isValueInArray(v,a){var l=a.length;for(var i=0;i<l;i++){if(a[i][0]==v){return true;}}return false;}function setHeadersCss(table,$headers,list,css){$headers.removeClass(css[0]).removeClass(css[1]);var h=[];$headers.each(function(offset){if(!this.sortDisabled){h[this.column]=$(this);}});var l=list.length;for(var i=0;i<l;i++){h[list[i][0]].addClass(css[list[i][1]]);}}function fixColumnWidth(table,$headers){var c=table.config;if(c.widthFixed){var colgroup=$('<colgroup>');$("tr:first td",table.tBodies[0]).each(function(){colgroup.append($('<col>').css('width',$(this).width()));});$(table).prepend(colgroup);};}function updateHeaderSortCount(table,sortList){var c=table.config,l=sortList.length;for(var i=0;i<l;i++){var s=sortList[i],o=c.headerList[s[0]];o.count=s[1];o.count++;}}function multisort(table,sortList,cache){if(table.config.debug){var sortTime=new Date();}var dynamicExp="var sortWrapper = function(a,b) {",l=sortList.length;for(var i=0;i<l;i++){var c=sortList[i][0];var order=sortList[i][1];var s=(table.config.parsers[c].type=="text")?((order==0)?makeSortFunction("text","asc",c):makeSortFunction("text","desc",c)):((order==0)?makeSortFunction("numeric","asc",c):makeSortFunction("numeric","desc",c));var e="e"+i;dynamicExp+="var "+e+" = "+s;dynamicExp+="if("+e+") { return "+e+"; } ";dynamicExp+="else { ";}var orgOrderCol=cache.normalized[0].length-1;dynamicExp+="return a["+orgOrderCol+"]-b["+orgOrderCol+"];";for(var i=0;i<l;i++){dynamicExp+="}; ";}dynamicExp+="return 0; ";dynamicExp+="}; ";if(table.config.debug){benchmark("Evaling expression:"+dynamicExp,new Date());}eval(dynamicExp);cache.normalized.sort(sortWrapper);if(table.config.debug){benchmark("Sorting on "+sortList.toString()+" and dir "+order+" time:",sortTime);}return cache;};function makeSortFunction(type,direction,index){var a="a["+index+"]",b="b["+index+"]";if(type=='text'&&direction=='asc'){return"("+a+" == "+b+" ? 0 : ("+a+" === null ? Number.POSITIVE_INFINITY : ("+b+" === null ? Number.NEGATIVE_INFINITY : ("+a+" < "+b+") ? -1 : 1 )));";}else if(type=='text'&&direction=='desc'){return"("+a+" == "+b+" ? 0 : ("+a+" === null ? Number.POSITIVE_INFINITY : ("+b+" === null ? Number.NEGATIVE_INFINITY : ("+b+" < "+a+") ? -1 : 1 )));";}else if(type=='numeric'&&direction=='asc'){return"("+a+" === null && "+b+" === null) ? 0 :("+a+" === null ? Number.POSITIVE_INFINITY : ("+b+" === null ? Number.NEGATIVE_INFINITY : "+a+" - "+b+"));";}else if(type=='numeric'&&direction=='desc'){return"("+a+" === null && "+b+" === null) ? 0 :("+a+" === null ? Number.POSITIVE_INFINITY : ("+b+" === null ? Number.NEGATIVE_INFINITY : "+b+" - "+a+"));";}};function makeSortText(i){return"((a["+i+"] < b["+i+"]) ? -1 : ((a["+i+"] > b["+i+"]) ? 1 : 0));";};function makeSortTextDesc(i){return"((b["+i+"] < a["+i+"]) ? -1 : ((b["+i+"] > a["+i+"]) ? 1 : 0));";};function makeSortNumeric(i){return"a["+i+"]-b["+i+"];";};function makeSortNumericDesc(i){return"b["+i+"]-a["+i+"];";};function sortText(a,b){if(table.config.sortLocaleCompare)return a.localeCompare(b);return((a<b)?-1:((a>b)?1:0));};function sortTextDesc(a,b){if(table.config.sortLocaleCompare)return b.localeCompare(a);return((b<a)?-1:((b>a)?1:0));};function sortNumeric(a,b){return a-b;};function sortNumericDesc(a,b){return b-a;};function getCachedSortType(parsers,i){return parsers[i].type;};this.construct=function(settings){return this.each(function(){if(!this.tHead||!this.tBodies)return;var $this,$document,$headers,cache,config,shiftDown=0,sortOrder;this.config={};config=$.extend(this.config,$.tablesorter.defaults,settings);$this=$(this);$.data(this,"tablesorter",config);$headers=buildHeaders(this);this.config.parsers=buildParserCache(this,$headers);cache=buildCache(this);var sortCSS=[config.cssDesc,config.cssAsc];fixColumnWidth(this);$headers.click(function(e){var totalRows=($this[0].tBodies[0]&&$this[0].tBodies[0].rows.length)||0;if(!this.sortDisabled&&totalRows>0){$this.trigger("sortStart");var $cell=$(this);var i=this.column;this.order=this.count++%2;if(this.lockedOrder)this.order=this.lockedOrder;if(!e[config.sortMultiSortKey]){config.sortList=[];if(config.sortForce!=null){var a=config.sortForce;for(var j=0;j<a.length;j++){if(a[j][0]!=i){config.sortList.push(a[j]);}}}config.sortList.push([i,this.order]);}else{if(isValueInArray(i,config.sortList)){for(var j=0;j<config.sortList.length;j++){var s=config.sortList[j],o=config.headerList[s[0]];if(s[0]==i){o.count=s[1];o.count++;s[1]=o.count%2;}}}else{config.sortList.push([i,this.order]);}};setTimeout(function(){setHeadersCss($this[0],$headers,config.sortList,sortCSS);appendToTable($this[0],multisort($this[0],config.sortList,cache));},1);return false;}}).mousedown(function(){if(config.cancelSelection){this.onselectstart=function(){return false};return false;}});$this.bind("update",function(){var me=this;setTimeout(function(){me.config.parsers=buildParserCache(me,$headers);cache=buildCache(me);},1);}).bind("updateCell",function(e,cell){var config=this.config;var pos=[(cell.parentNode.rowIndex-1),cell.cellIndex];cache.normalized[pos[0]][pos[1]]=config.parsers[pos[1]].format(getElementText(config,cell),cell);}).bind("sorton",function(e,list){$(this).trigger("sortStart");config.sortList=list;var sortList=config.sortList;updateHeaderSortCount(this,sortList);setHeadersCss(this,$headers,sortList,sortCSS);appendToTable(this,multisort(this,sortList,cache));}).bind("appendCache",function(){appendToTable(this,cache);}).bind("applyWidgetId",function(e,id){getWidgetById(id).format(this);}).bind("applyWidgets",function(){applyWidget(this);});if($.metadata&&($(this).metadata()&&$(this).metadata().sortlist)){config.sortList=$(this).metadata().sortlist;}if(config.sortList.length>0){$this.trigger("sorton",[config.sortList]);}applyWidget(this);});};this.addParser=function(parser){var l=parsers.length,a=true;for(var i=0;i<l;i++){if(parsers[i].id.toLowerCase()==parser.id.toLowerCase()){a=false;}}if(a){parsers.push(parser);};};this.addWidget=function(widget){widgets.push(widget);};this.formatFloat=function(s){var i=parseFloat(s);return(isNaN(i))?0:i;};this.formatInt=function(s){var i=parseInt(s);return(isNaN(i))?0:i;};this.isDigit=function(s,config){return/^[-+]?\d*$/.test($.trim(s.replace(/[,.']/g,'')));};this.clearTableBody=function(table){if($.browser.msie){function empty(){while(this.firstChild)this.removeChild(this.firstChild);}empty.apply(table.tBodies[0]);}else{table.tBodies[0].innerHTML="";}};}});$.fn.extend({tablesorter:$.tablesorter.construct});var ts=$.tablesorter;ts.addParser({id:"text",is:function(s){return true;},format:function(s){return $.trim(s.toLocaleLowerCase());},type:"text"});ts.addParser({id:"digit",is:function(s,table){var c=table.config;return $.tablesorter.isDigit(s,c);},format:function(s){return $.tablesorter.formatFloat(s);},type:"numeric"});ts.addParser({id:"currency",is:function(s){return/^[£$€?.]/.test(s);},format:function(s){return $.tablesorter.formatFloat(s.replace(new RegExp(/[£$€]/g),""));},type:"numeric"});ts.addParser({id:"ipAddress",is:function(s){return/^\d{2,3}[\.]\d{2,3}[\.]\d{2,3}[\.]\d{2,3}$/.test(s);},format:function(s){var a=s.split("."),r="",l=a.length;for(var i=0;i<l;i++){var item=a[i];if(item.length==2){r+="0"+item;}else{r+=item;}}return $.tablesorter.formatFloat(r);},type:"numeric"});ts.addParser({id:"url",is:function(s){return/^(https?|ftp|file):\/\/$/.test(s);},format:function(s){return jQuery.trim(s.replace(new RegExp(/(https?|ftp|file):\/\//),''));},type:"text"});ts.addParser({id:"isoDate",is:function(s){return/^\d{4}[\/-]\d{1,2}[\/-]\d{1,2}$/.test(s);},format:function(s){return $.tablesorter.formatFloat((s!="")?new Date(s.replace(new RegExp(/-/g),"/")).getTime():"0");},type:"numeric"});ts.addParser({id:"percent",is:function(s){return/\%$/.test($.trim(s));},format:function(s){return $.tablesorter.formatFloat(s.replace(new RegExp(/%/g),""));},type:"numeric"});ts.addParser({id:"usLongDate",is:function(s){return s.match(new RegExp(/^[A-Za-z]{3,10}\.? [0-9]{1,2}, ([0-9]{4}|'?[0-9]{2}) (([0-2]?[0-9]:[0-5][0-9])|([0-1]?[0-9]:[0-5][0-9]\s(AM|PM)))$/));},format:function(s){return $.tablesorter.formatFloat(new Date(s).getTime());},type:"numeric"});ts.addParser({id:"shortDate",is:function(s){return/\d{1,2}[\/\-]\d{1,2}[\/\-]\d{2,4}/.test(s);},format:function(s,table){var c=table.config;s=s.replace(/\-/g,"/");if(c.dateFormat=="us"){s=s.replace(/(\d{1,2})[\/\-](\d{1,2})[\/\-](\d{4})/,"$3/$1/$2");}else if(c.dateFormat=="uk"){s=s.replace(/(\d{1,2})[\/\-](\d{1,2})[\/\-](\d{4})/,"$3/$2/$1");}else if(c.dateFormat=="dd/mm/yy"||c.dateFormat=="dd-mm-yy"){s=s.replace(/(\d{1,2})[\/\-](\d{1,2})[\/\-](\d{2})/,"$1/$2/$3");}return $.tablesorter.formatFloat(new Date(s).getTime());},type:"numeric"});ts.addParser({id:"time",is:function(s){return/^(([0-2]?[0-9]:[0-5][0-9])|([0-1]?[0-9]:[0-5][0-9]\s(am|pm)))$/.test(s);},format:function(s){return $.tablesorter.formatFloat(new Date("2000/01/01 "+s).getTime());},type:"numeric"});ts.addParser({id:"metadata",is:function(s){return false;},format:function(s,table,cell){var c=table.config,p=(!c.parserMetadataName)?'sortValue':c.parserMetadataName;return $(cell).metadata()[p];},type:"numeric"});ts.addWidget({id:"zebra",format:function(table){if(table.config.debug){var time=new Date();}var $tr,row=-1,odd;$("tr:visible",table.tBodies[0]).each(function(i){$tr=$(this);if(!$tr.hasClass(table.config.cssChildRow))row++;odd=(row%2==0);$tr.removeClass(table.config.widgetZebra.css[odd?0:1]).addClass(table.config.widgetZebra.css[odd?1:0])});if(table.config.debug){$.tablesorter.benchmark("Applying Zebra widget",time);}}});})(jQuery);
 548 </script>
 549 <script type="text/javascript">
 550 $(document).ready(function() {
 551     $("table.tablesorter").tablesorter();
 552 });
 553 </script>
 554 </body>
 555 </html>
 556 EOM
 557     return join("\n", @output);
 558 }
 559
 560 # Output NIC list in DokuWiki format (for http://ipxe.org)
 561 sub format_nic_list_dokuwiki {
 562     my ($nic_list, $column_names) = @_;
 563     my @output;
 564
 565     push @output, <<'EOM';
 566 EOM
 567
 568     # Output DokuWiki table header
 569     push @output, "^"
 570                 . join("^",
 571                     map { $_ || "" }
 572                     @$column_names
 573                   )
 574                 . "^";
 575
 576     # Output DokuWiki table entries
 577     foreach my $nic ( @$nic_list ) {
 578         my @columns = @{ $nic }{ @$column_names }; # array slice from hashref, see perldoc perldata if confusing
 579         push @output, '|'
 580                     . join('|',
 581                         map { $_ || "" }
 582                         @columns
 583                       )
 584                     . '|';
 585     }
 586
 587     return join("\n", @output);
 588 }