meson: target
[qemu.git] / target / arm / meson.build
1 gen = [
2   decodetree.process('sve.decode', extra_args: '--decode=disas_sve'),
3   decodetree.process('neon-shared.decode', extra_args: '--static-decode=disas_neon_shared'),
4   decodetree.process('neon-dp.decode', extra_args: '--static-decode=disas_neon_dp'),
5   decodetree.process('neon-ls.decode', extra_args: '--static-decode=disas_neon_ls'),
6   decodetree.process('vfp.decode', extra_args: '--static-decode=disas_vfp'),
7   decodetree.process('vfp-uncond.decode', extra_args: '--static-decode=disas_vfp_uncond'),
8   decodetree.process('a32.decode', extra_args: '--static-decode=disas_a32'),
9   decodetree.process('a32-uncond.decode', extra_args: '--static-decode=disas_a32_uncond'),
10   decodetree.process('t32.decode', extra_args: '--static-decode=disas_t32'),
11   decodetree.process('t16.decode', extra_args: ['-w', '16', '--static-decode=disas_t16']),
12 ]
13
14 arm_ss = ss.source_set()
15 arm_ss.add(gen)
16 arm_ss.add(files(
17   'cpu.c',
18   'crypto_helper.c',
19   'debug_helper.c',
20   'gdbstub.c',
21   'helper.c',
22   'iwmmxt_helper.c',
23   'm_helper.c',
24   'neon_helper.c',
25   'op_helper.c',
26   'tlb_helper.c',
27   'translate.c',
28   'vec_helper.c',
29   'vfp_helper.c',
30   'cpu_tcg.c',
31 ))
32 arm_ss.add(zlib)
33
34 arm_ss.add(when: 'CONFIG_TCG', if_true: files('arm-semi.c'))
35
36 kvm_ss = ss.source_set()
37 kvm_ss.add(when: 'TARGET_AARCH64', if_true: files('kvm64.c'), if_false: files('kvm32.c'))
38 arm_ss.add_all(when: 'CONFIG_KVM', if_true: kvm_ss)
39 arm_ss.add(when: 'CONFIG_KVM', if_true: files('kvm.c'), if_false: files('kvm-stub.c'))
40
41 arm_ss.add(when: 'TARGET_AARCH64', if_true: files(
42   'cpu64.c',
43   'gdbstub64.c',
44   'helper-a64.c',
45   'mte_helper.c',
46   'pauth_helper.c',
47   'sve_helper.c',
48   'translate-a64.c',
49   'translate-sve.c',
50 ))
51
52 arm_softmmu_ss = ss.source_set()
53 arm_softmmu_ss.add(files(
54   'arch_dump.c',
55   'arm-powerctl.c',
56   'machine.c',
57   'monitor.c',
58   'psci.c',
59 ))
60
61 target_arch += {'arm': arm_ss}
62 target_softmmu_arch += {'arm': arm_softmmu_ss}