migration: increase max-bandwidth to 128 MiB/s (1 Gib/s)
[qemu.git] / target / arm / meson.build
1 gen = [
2   decodetree.process('sve.decode', extra_args: '--decode=disas_sve'),
3   decodetree.process('neon-shared.decode', extra_args: '--static-decode=disas_neon_shared'),
4   decodetree.process('neon-dp.decode', extra_args: '--static-decode=disas_neon_dp'),
5   decodetree.process('neon-ls.decode', extra_args: '--static-decode=disas_neon_ls'),
6   decodetree.process('vfp.decode', extra_args: '--static-decode=disas_vfp'),
7   decodetree.process('vfp-uncond.decode', extra_args: '--static-decode=disas_vfp_uncond'),
8   decodetree.process('m-nocp.decode', extra_args: '--static-decode=disas_m_nocp'),
9   decodetree.process('a32.decode', extra_args: '--static-decode=disas_a32'),
10   decodetree.process('a32-uncond.decode', extra_args: '--static-decode=disas_a32_uncond'),
11   decodetree.process('t32.decode', extra_args: '--static-decode=disas_t32'),
12   decodetree.process('t16.decode', extra_args: ['-w', '16', '--static-decode=disas_t16']),
13 ]
14
15 arm_ss = ss.source_set()
16 arm_ss.add(gen)
17 arm_ss.add(files(
18   'cpu.c',
19   'crypto_helper.c',
20   'debug_helper.c',
21   'gdbstub.c',
22   'helper.c',
23   'iwmmxt_helper.c',
24   'm_helper.c',
25   'neon_helper.c',
26   'op_helper.c',
27   'tlb_helper.c',
28   'translate.c',
29   'vec_helper.c',
30   'vfp_helper.c',
31   'cpu_tcg.c',
32 ))
33 arm_ss.add(zlib)
34
35 arm_ss.add(when: 'CONFIG_TCG', if_true: files('arm-semi.c'))
36
37 arm_ss.add(when: 'CONFIG_KVM', if_true: files('kvm.c', 'kvm64.c'), if_false: files('kvm-stub.c'))
38
39 arm_ss.add(when: 'TARGET_AARCH64', if_true: files(
40   'cpu64.c',
41   'gdbstub64.c',
42   'helper-a64.c',
43   'mte_helper.c',
44   'pauth_helper.c',
45   'sve_helper.c',
46   'translate-a64.c',
47   'translate-sve.c',
48 ))
49
50 arm_softmmu_ss = ss.source_set()
51 arm_softmmu_ss.add(files(
52   'arch_dump.c',
53   'arm-powerctl.c',
54   'machine.c',
55   'monitor.c',
56   'psci.c',
57 ))
58
59 target_arch += {'arm': arm_ss}
60 target_softmmu_arch += {'arm': arm_softmmu_ss}