Merge tag 'block-pull-request' of https://gitlab.com/stefanha/qemu into staging
[qemu.git] / target / arm / meson.build
1 gen = [
2   decodetree.process('sve.decode', extra_args: '--decode=disas_sve'),
3   decodetree.process('sme.decode', extra_args: '--decode=disas_sme'),
4   decodetree.process('sme-fa64.decode', extra_args: '--static-decode=disas_sme_fa64'),
5   decodetree.process('neon-shared.decode', extra_args: '--decode=disas_neon_shared'),
6   decodetree.process('neon-dp.decode', extra_args: '--decode=disas_neon_dp'),
7   decodetree.process('neon-ls.decode', extra_args: '--decode=disas_neon_ls'),
8   decodetree.process('vfp.decode', extra_args: '--decode=disas_vfp'),
9   decodetree.process('vfp-uncond.decode', extra_args: '--decode=disas_vfp_uncond'),
10   decodetree.process('m-nocp.decode', extra_args: '--decode=disas_m_nocp'),
11   decodetree.process('mve.decode', extra_args: '--decode=disas_mve'),
12   decodetree.process('a32.decode', extra_args: '--static-decode=disas_a32'),
13   decodetree.process('a32-uncond.decode', extra_args: '--static-decode=disas_a32_uncond'),
14   decodetree.process('t32.decode', extra_args: '--static-decode=disas_t32'),
15   decodetree.process('t16.decode', extra_args: ['-w', '16', '--static-decode=disas_t16']),
16 ]
17
18 arm_ss = ss.source_set()
19 arm_ss.add(gen)
20 arm_ss.add(files(
21   'cpu.c',
22   'crypto_helper.c',
23   'debug_helper.c',
24   'gdbstub.c',
25   'helper.c',
26   'iwmmxt_helper.c',
27   'm_helper.c',
28   'mve_helper.c',
29   'neon_helper.c',
30   'op_helper.c',
31   'tlb_helper.c',
32   'translate.c',
33   'translate-m-nocp.c',
34   'translate-mve.c',
35   'translate-neon.c',
36   'translate-vfp.c',
37   'vec_helper.c',
38   'vfp_helper.c',
39   'cpu_tcg.c',
40 ))
41 arm_ss.add(zlib)
42
43 arm_ss.add(when: 'CONFIG_KVM', if_true: files('kvm.c', 'kvm64.c'), if_false: files('kvm-stub.c'))
44
45 arm_ss.add(when: 'TARGET_AARCH64', if_true: files(
46   'cpu64.c',
47   'gdbstub64.c',
48   'helper-a64.c',
49   'mte_helper.c',
50   'pauth_helper.c',
51   'sve_helper.c',
52   'sme_helper.c',
53   'translate-a64.c',
54   'translate-sve.c',
55   'translate-sme.c',
56 ))
57
58 arm_softmmu_ss = ss.source_set()
59 arm_softmmu_ss.add(files(
60   'arch_dump.c',
61   'arm-powerctl.c',
62   'machine.c',
63   'monitor.c',
64   'psci.c',
65   'ptw.c',
66 ))
67
68 subdir('hvf')
69
70 target_arch += {'arm': arm_ss}
71 target_softmmu_arch += {'arm': arm_softmmu_ss}