hw/arm/virt: parameter passing cleanups
[qemu.git] / tcg / README
1 Tiny Code Generator - Fabrice Bellard.
2
3 1) Introduction
4
5 TCG (Tiny Code Generator) began as a generic backend for a C
6 compiler. It was simplified to be used in QEMU. It also has its roots
7 in the QOP code generator written by Paul Brook. 
8
9 2) Definitions
10
11 TCG receives RISC-like "TCG ops" and performs some optimizations on them,
12 including liveness analysis and trivial constant expression
13 evaluation.  TCG ops are then implemented in the host CPU back end,
14 also known as the TCG "target".
15
16 The TCG "target" is the architecture for which we generate the
17 code. It is of course not the same as the "target" of QEMU which is
18 the emulated architecture. As TCG started as a generic C backend used
19 for cross compiling, it is assumed that the TCG target is different
20 from the host, although it is never the case for QEMU.
21
22 In this document, we use "guest" to specify what architecture we are
23 emulating; "target" always means the TCG target, the machine on which
24 we are running QEMU.
25
26 A TCG "function" corresponds to a QEMU Translated Block (TB).
27
28 A TCG "temporary" is a variable only live in a basic
29 block. Temporaries are allocated explicitly in each function.
30
31 A TCG "local temporary" is a variable only live in a function. Local
32 temporaries are allocated explicitly in each function.
33
34 A TCG "global" is a variable which is live in all the functions
35 (equivalent of a C global variable). They are defined before the
36 functions defined. A TCG global can be a memory location (e.g. a QEMU
37 CPU register), a fixed host register (e.g. the QEMU CPU state pointer)
38 or a memory location which is stored in a register outside QEMU TBs
39 (not implemented yet).
40
41 A TCG "basic block" corresponds to a list of instructions terminated
42 by a branch instruction. 
43
44 An operation with "undefined behavior" may result in a crash.
45
46 An operation with "unspecified behavior" shall not crash.  However,
47 the result may be one of several possibilities so may be considered
48 an "undefined result".
49
50 3) Intermediate representation
51
52 3.1) Introduction
53
54 TCG instructions operate on variables which are temporaries, local
55 temporaries or globals. TCG instructions and variables are strongly
56 typed. Two types are supported: 32 bit integers and 64 bit
57 integers. Pointers are defined as an alias to 32 bit or 64 bit
58 integers depending on the TCG target word size.
59
60 Each instruction has a fixed number of output variable operands, input
61 variable operands and always constant operands.
62
63 The notable exception is the call instruction which has a variable
64 number of outputs and inputs.
65
66 In the textual form, output operands usually come first, followed by
67 input operands, followed by constant operands. The output type is
68 included in the instruction name. Constants are prefixed with a '$'.
69
70 add_i32 t0, t1, t2  (t0 <- t1 + t2)
71
72 3.2) Assumptions
73
74 * Basic blocks
75
76 - Basic blocks end after branches (e.g. brcond_i32 instruction),
77   goto_tb and exit_tb instructions.
78 - Basic blocks start after the end of a previous basic block, or at a
79   set_label instruction.
80
81 After the end of a basic block, the content of temporaries is
82 destroyed, but local temporaries and globals are preserved.
83
84 * Floating point types are not supported yet
85
86 * Pointers: depending on the TCG target, pointer size is 32 bit or 64
87   bit. The type TCG_TYPE_PTR is an alias to TCG_TYPE_I32 or
88   TCG_TYPE_I64.
89
90 * Helpers:
91
92 Using the tcg_gen_helper_x_y it is possible to call any function
93 taking i32, i64 or pointer types. By default, before calling a helper,
94 all globals are stored at their canonical location and it is assumed
95 that the function can modify them. By default, the helper is allowed to
96 modify the CPU state or raise an exception.
97
98 This can be overridden using the following function modifiers:
99 - TCG_CALL_NO_READ_GLOBALS means that the helper does not read globals,
100   either directly or via an exception. They will not be saved to their
101   canonical locations before calling the helper.
102 - TCG_CALL_NO_WRITE_GLOBALS means that the helper does not modify any globals.
103   They will only be saved to their canonical location before calling helpers,
104   but they won't be reloaded afterwise.
105 - TCG_CALL_NO_SIDE_EFFECTS means that the call to the function is removed if
106   the return value is not used.
107
108 Note that TCG_CALL_NO_READ_GLOBALS implies TCG_CALL_NO_WRITE_GLOBALS.
109
110 On some TCG targets (e.g. x86), several calling conventions are
111 supported.
112
113 * Branches:
114
115 Use the instruction 'br' to jump to a label.
116
117 3.3) Code Optimizations
118
119 When generating instructions, you can count on at least the following
120 optimizations:
121
122 - Single instructions are simplified, e.g.
123
124    and_i32 t0, t0, $0xffffffff
125     
126   is suppressed.
127
128 - A liveness analysis is done at the basic block level. The
129   information is used to suppress moves from a dead variable to
130   another one. It is also used to remove instructions which compute
131   dead results. The later is especially useful for condition code
132   optimization in QEMU.
133
134   In the following example:
135
136   add_i32 t0, t1, t2
137   add_i32 t0, t0, $1
138   mov_i32 t0, $1
139
140   only the last instruction is kept.
141
142 3.4) Instruction Reference
143
144 ********* Function call
145
146 * call <ret> <params> ptr
147
148 call function 'ptr' (pointer type)
149
150 <ret> optional 32 bit or 64 bit return value
151 <params> optional 32 bit or 64 bit parameters
152
153 ********* Jumps/Labels
154
155 * set_label $label
156
157 Define label 'label' at the current program point.
158
159 * br $label
160
161 Jump to label.
162
163 * brcond_i32/i64 t0, t1, cond, label
164
165 Conditional jump if t0 cond t1 is true. cond can be:
166     TCG_COND_EQ
167     TCG_COND_NE
168     TCG_COND_LT /* signed */
169     TCG_COND_GE /* signed */
170     TCG_COND_LE /* signed */
171     TCG_COND_GT /* signed */
172     TCG_COND_LTU /* unsigned */
173     TCG_COND_GEU /* unsigned */
174     TCG_COND_LEU /* unsigned */
175     TCG_COND_GTU /* unsigned */
176
177 ********* Arithmetic
178
179 * add_i32/i64 t0, t1, t2
180
181 t0=t1+t2
182
183 * sub_i32/i64 t0, t1, t2
184
185 t0=t1-t2
186
187 * neg_i32/i64 t0, t1
188
189 t0=-t1 (two's complement)
190
191 * mul_i32/i64 t0, t1, t2
192
193 t0=t1*t2
194
195 * div_i32/i64 t0, t1, t2
196
197 t0=t1/t2 (signed). Undefined behavior if division by zero or overflow.
198
199 * divu_i32/i64 t0, t1, t2
200
201 t0=t1/t2 (unsigned). Undefined behavior if division by zero.
202
203 * rem_i32/i64 t0, t1, t2
204
205 t0=t1%t2 (signed). Undefined behavior if division by zero or overflow.
206
207 * remu_i32/i64 t0, t1, t2
208
209 t0=t1%t2 (unsigned). Undefined behavior if division by zero.
210
211 ********* Logical
212
213 * and_i32/i64 t0, t1, t2
214
215 t0=t1&t2
216
217 * or_i32/i64 t0, t1, t2
218
219 t0=t1|t2
220
221 * xor_i32/i64 t0, t1, t2
222
223 t0=t1^t2
224
225 * not_i32/i64 t0, t1
226
227 t0=~t1
228
229 * andc_i32/i64 t0, t1, t2
230
231 t0=t1&~t2
232
233 * eqv_i32/i64 t0, t1, t2
234
235 t0=~(t1^t2), or equivalently, t0=t1^~t2
236
237 * nand_i32/i64 t0, t1, t2
238
239 t0=~(t1&t2)
240
241 * nor_i32/i64 t0, t1, t2
242
243 t0=~(t1|t2)
244
245 * orc_i32/i64 t0, t1, t2
246
247 t0=t1|~t2
248
249 ********* Shifts/Rotates
250
251 * shl_i32/i64 t0, t1, t2
252
253 t0=t1 << t2. Unspecified behavior if t2 < 0 or t2 >= 32 (resp 64)
254
255 * shr_i32/i64 t0, t1, t2
256
257 t0=t1 >> t2 (unsigned). Unspecified behavior if t2 < 0 or t2 >= 32 (resp 64)
258
259 * sar_i32/i64 t0, t1, t2
260
261 t0=t1 >> t2 (signed). Unspecified behavior if t2 < 0 or t2 >= 32 (resp 64)
262
263 * rotl_i32/i64 t0, t1, t2
264
265 Rotation of t2 bits to the left.
266 Unspecified behavior if t2 < 0 or t2 >= 32 (resp 64)
267
268 * rotr_i32/i64 t0, t1, t2
269
270 Rotation of t2 bits to the right.
271 Unspecified behavior if t2 < 0 or t2 >= 32 (resp 64)
272
273 ********* Misc
274
275 * mov_i32/i64 t0, t1
276
277 t0 = t1
278
279 Move t1 to t0 (both operands must have the same type).
280
281 * ext8s_i32/i64 t0, t1
282 ext8u_i32/i64 t0, t1
283 ext16s_i32/i64 t0, t1
284 ext16u_i32/i64 t0, t1
285 ext32s_i64 t0, t1
286 ext32u_i64 t0, t1
287
288 8, 16 or 32 bit sign/zero extension (both operands must have the same type)
289
290 * bswap16_i32/i64 t0, t1
291
292 16 bit byte swap on a 32/64 bit value. It assumes that the two/six high order
293 bytes are set to zero.
294
295 * bswap32_i32/i64 t0, t1
296
297 32 bit byte swap on a 32/64 bit value. With a 64 bit value, it assumes that
298 the four high order bytes are set to zero.
299
300 * bswap64_i64 t0, t1
301
302 64 bit byte swap
303
304 * discard_i32/i64 t0
305
306 Indicate that the value of t0 won't be used later. It is useful to
307 force dead code elimination.
308
309 * deposit_i32/i64 dest, t1, t2, pos, len
310
311 Deposit T2 as a bitfield into T1, placing the result in DEST.
312 The bitfield is described by POS/LEN, which are immediate values:
313
314   LEN - the length of the bitfield
315   POS - the position of the first bit, counting from the LSB
316
317 For example, pos=8, len=4 indicates a 4-bit field at bit 8.
318 This operation would be equivalent to
319
320   dest = (t1 & ~0x0f00) | ((t2 << 8) & 0x0f00)
321
322 * extrl_i64_i32 t0, t1
323
324 For 64-bit hosts only, extract the low 32-bits of input T1 and place it
325 into 32-bit output T0.  Depending on the host, this may be a simple move,
326 or may require additional canonicalization.
327
328 * extrh_i64_i32 t0, t1
329
330 For 64-bit hosts only, extract the high 32-bits of input T1 and place it
331 into 32-bit output T0.  Depending on the host, this may be a simple shift,
332 or may require additional canonicalization.
333
334 ********* Conditional moves
335
336 * setcond_i32/i64 dest, t1, t2, cond
337
338 dest = (t1 cond t2)
339
340 Set DEST to 1 if (T1 cond T2) is true, otherwise set to 0.
341
342 * movcond_i32/i64 dest, c1, c2, v1, v2, cond
343
344 dest = (c1 cond c2 ? v1 : v2)
345
346 Set DEST to V1 if (C1 cond C2) is true, otherwise set to V2.
347
348 ********* Type conversions
349
350 * ext_i32_i64 t0, t1
351 Convert t1 (32 bit) to t0 (64 bit) and does sign extension
352
353 * extu_i32_i64 t0, t1
354 Convert t1 (32 bit) to t0 (64 bit) and does zero extension
355
356 * trunc_i64_i32 t0, t1
357 Truncate t1 (64 bit) to t0 (32 bit)
358
359 * concat_i32_i64 t0, t1, t2
360 Construct t0 (64-bit) taking the low half from t1 (32 bit) and the high half
361 from t2 (32 bit).
362
363 * concat32_i64 t0, t1, t2
364 Construct t0 (64-bit) taking the low half from t1 (64 bit) and the high half
365 from t2 (64 bit).
366
367 ********* Load/Store
368
369 * ld_i32/i64 t0, t1, offset
370 ld8s_i32/i64 t0, t1, offset
371 ld8u_i32/i64 t0, t1, offset
372 ld16s_i32/i64 t0, t1, offset
373 ld16u_i32/i64 t0, t1, offset
374 ld32s_i64 t0, t1, offset
375 ld32u_i64 t0, t1, offset
376
377 t0 = read(t1 + offset)
378 Load 8, 16, 32 or 64 bits with or without sign extension from host memory. 
379 offset must be a constant.
380
381 * st_i32/i64 t0, t1, offset
382 st8_i32/i64 t0, t1, offset
383 st16_i32/i64 t0, t1, offset
384 st32_i64 t0, t1, offset
385
386 write(t0, t1 + offset)
387 Write 8, 16, 32 or 64 bits to host memory.
388
389 All this opcodes assume that the pointed host memory doesn't correspond
390 to a global. In the latter case the behaviour is unpredictable.
391
392 ********* Multiword arithmetic support
393
394 * add2_i32/i64 t0_low, t0_high, t1_low, t1_high, t2_low, t2_high
395 * sub2_i32/i64 t0_low, t0_high, t1_low, t1_high, t2_low, t2_high
396
397 Similar to add/sub, except that the double-word inputs T1 and T2 are
398 formed from two single-word arguments, and the double-word output T0
399 is returned in two single-word outputs.
400
401 * mulu2_i32/i64 t0_low, t0_high, t1, t2
402
403 Similar to mul, except two unsigned inputs T1 and T2 yielding the full
404 double-word product T0.  The later is returned in two single-word outputs.
405
406 * muls2_i32/i64 t0_low, t0_high, t1, t2
407
408 Similar to mulu2, except the two inputs T1 and T2 are signed.
409
410 ********* Memory Barrier support
411
412 * mb <$arg>
413
414 Generate a target memory barrier instruction to ensure memory ordering as being
415 enforced by a corresponding guest memory barrier instruction. The ordering
416 enforced by the backend may be stricter than the ordering required by the guest.
417 It cannot be weaker. This opcode takes a constant argument which is required to
418 generate the appropriate barrier instruction. The backend should take care to
419 emit the target barrier instruction only when necessary i.e., for SMP guests and
420 when MTTCG is enabled.
421
422 The guest translators should generate this opcode for all guest instructions
423 which have ordering side effects.
424
425 Please see docs/atomics.txt for more information on memory barriers.
426
427 ********* 64-bit guest on 32-bit host support
428
429 The following opcodes are internal to TCG.  Thus they are to be implemented by
430 32-bit host code generators, but are not to be emitted by guest translators.
431 They are emitted as needed by inline functions within "tcg-op.h".
432
433 * brcond2_i32 t0_low, t0_high, t1_low, t1_high, cond, label
434
435 Similar to brcond, except that the 64-bit values T0 and T1
436 are formed from two 32-bit arguments.
437
438 * setcond2_i32 dest, t1_low, t1_high, t2_low, t2_high, cond
439
440 Similar to setcond, except that the 64-bit values T1 and T2 are
441 formed from two 32-bit arguments.  The result is a 32-bit value.
442
443 ********* QEMU specific operations
444
445 * exit_tb t0
446
447 Exit the current TB and return the value t0 (word type).
448
449 * goto_tb index
450
451 Exit the current TB and jump to the TB index 'index' (constant) if the
452 current TB was linked to this TB. Otherwise execute the next
453 instructions. Only indices 0 and 1 are valid and tcg_gen_goto_tb may be issued
454 at most once with each slot index per TB.
455
456 * qemu_ld_i32/i64 t0, t1, flags, memidx
457 * qemu_st_i32/i64 t0, t1, flags, memidx
458
459 Load data at the guest address t1 into t0, or store data in t0 at guest
460 address t1.  The _i32/_i64 size applies to the size of the input/output
461 register t0 only.  The address t1 is always sized according to the guest,
462 and the width of the memory operation is controlled by flags.
463
464 Both t0 and t1 may be split into little-endian ordered pairs of registers
465 if dealing with 64-bit quantities on a 32-bit host.
466
467 The memidx selects the qemu tlb index to use (e.g. user or kernel access).
468 The flags are the TCGMemOp bits, selecting the sign, width, and endianness
469 of the memory access.
470
471 For a 32-bit host, qemu_ld/st_i64 is guaranteed to only be used with a
472 64-bit memory access specified in flags.
473
474 *********
475
476 Note 1: Some shortcuts are defined when the last operand is known to be
477 a constant (e.g. addi for add, movi for mov).
478
479 Note 2: When using TCG, the opcodes must never be generated directly
480 as some of them may not be available as "real" opcodes. Always use the
481 function tcg_gen_xxx(args).
482
483 4) Backend
484
485 tcg-target.h contains the target specific definitions. tcg-target.inc.c
486 contains the target specific code; it is #included by tcg/tcg.c, rather
487 than being a standalone C file.
488
489 4.1) Assumptions
490
491 The target word size (TCG_TARGET_REG_BITS) is expected to be 32 bit or
492 64 bit. It is expected that the pointer has the same size as the word.
493
494 On a 32 bit target, all 64 bit operations are converted to 32 bits. A
495 few specific operations must be implemented to allow it (see add2_i32,
496 sub2_i32, brcond2_i32).
497
498 On a 64 bit target, the values are transferred between 32 and 64-bit
499 registers using the following ops:
500 - trunc_shr_i64_i32
501 - ext_i32_i64
502 - extu_i32_i64
503
504 They ensure that the values are correctly truncated or extended when
505 moved from a 32-bit to a 64-bit register or vice-versa. Note that the
506 trunc_shr_i64_i32 is an optional op. It is not necessary to implement
507 it if all the following conditions are met:
508 - 64-bit registers can hold 32-bit values
509 - 32-bit values in a 64-bit register do not need to stay zero or
510   sign extended
511 - all 32-bit TCG ops ignore the high part of 64-bit registers
512
513 Floating point operations are not supported in this version. A
514 previous incarnation of the code generator had full support of them,
515 but it is better to concentrate on integer operations first.
516
517 4.2) Constraints
518
519 GCC like constraints are used to define the constraints of every
520 instruction. Memory constraints are not supported in this
521 version. Aliases are specified in the input operands as for GCC.
522
523 The same register may be used for both an input and an output, even when
524 they are not explicitly aliased.  If an op expands to multiple target
525 instructions then care must be taken to avoid clobbering input values.
526 GCC style "early clobber" outputs are not currently supported.
527
528 A target can define specific register or constant constraints. If an
529 operation uses a constant input constraint which does not allow all
530 constants, it must also accept registers in order to have a fallback.
531
532 The movi_i32 and movi_i64 operations must accept any constants.
533
534 The mov_i32 and mov_i64 operations must accept any registers of the
535 same type.
536
537 The ld/st instructions must accept signed 32 bit constant offsets. It
538 can be implemented by reserving a specific register to compute the
539 address if the offset is too big.
540
541 The ld/st instructions must accept any destination (ld) or source (st)
542 register.
543
544 4.3) Function call assumptions
545
546 - The only supported types for parameters and return value are: 32 and
547   64 bit integers and pointer.
548 - The stack grows downwards.
549 - The first N parameters are passed in registers.
550 - The next parameters are passed on the stack by storing them as words.
551 - Some registers are clobbered during the call. 
552 - The function can return 0 or 1 value in registers. On a 32 bit
553   target, functions must be able to return 2 values in registers for
554   64 bit return type.
555
556 5) Recommended coding rules for best performance
557
558 - Use globals to represent the parts of the QEMU CPU state which are
559   often modified, e.g. the integer registers and the condition
560   codes. TCG will be able to use host registers to store them.
561
562 - Avoid globals stored in fixed registers. They must be used only to
563   store the pointer to the CPU state and possibly to store a pointer
564   to a register window.
565
566 - Use temporaries. Use local temporaries only when really needed,
567   e.g. when you need to use a value after a jump. Local temporaries
568   introduce a performance hit in the current TCG implementation: their
569   content is saved to memory at end of each basic block.
570
571 - Free temporaries and local temporaries when they are no longer used
572   (tcg_temp_free). Since tcg_const_x() also creates a temporary, you
573   should free it after it is used. Freeing temporaries does not yield
574   a better generated code, but it reduces the memory usage of TCG and
575   the speed of the translation.
576
577 - Don't hesitate to use helpers for complicated or seldom used guest
578   instructions. There is little performance advantage in using TCG to
579   implement guest instructions taking more than about twenty TCG
580   instructions. Note that this rule of thumb is more applicable to
581   helpers doing complex logic or arithmetic, where the C compiler has
582   scope to do a good job of optimisation; it is less relevant where
583   the instruction is mostly doing loads and stores, and in those cases
584   inline TCG may still be faster for longer sequences.
585
586 - The hard limit on the number of TCG instructions you can generate
587   per guest instruction is set by MAX_OP_PER_INSTR in exec-all.h --
588   you cannot exceed this without risking a buffer overrun.
589
590 - Use the 'discard' instruction if you know that TCG won't be able to
591   prove that a given global is "dead" at a given program point. The
592   x86 guest uses it to improve the condition codes optimisation.